验证6种信用卡卡号的代码其他

验证6种信用卡卡号的代码作者:BEUS 日期:2006-08-25 字体大小: 小中大可以验证的信用卡种类有：
V - Visa
M - MasterCard
A - American Express
D - Diners Club
Discover - Discover
JCB - JCB
【验证6种信用卡卡号的代码】以下为ASP代码：
Function ValidateCreditCard(ByRef pStrNumber, ByRef pStrType)
ValidateCreditCard = FALSE ' Initialize negative results

' Clean Credit Card Number (Removes dashes and spaces)
pStrNumber = ParseDigits(pStrNumber)

' Validate number with LUHN Formula
If Not LUHN(pStrNumber) Then Exit Function

' Apply rules based on type of card
Select Case pStrType
Case "A"
Select Case Left(pStrNumber, 2)
Case "34", "37"
' Do Nothing
Case Else
Exit Function
End Select
If Not Len(pStrNumber) = 15 Then Exit Function
Case "D"
Select Case Left(pStrNumber, 2)
Case "36" , "38"
' Do Nothing
Case "30"
Select Case Left(pStrNumber, 3)
Case "300", "301", "302", "303", "304", "305"
' Do Nothing
Case Else
Exit Function
End Select
Case Else
Exit Function
End Select
If Not Len(pStrNumber) = 14 Then Exit Function
Case "Discover"
If Not Left(pStrNumber, 4) = "6011" Then Exit Function
If Not Len(pStrNumber) = 16 Then Exit Function
Case "JCB"
If Left(pStrNumber, 1) = "3" And Len(pStrNumber) = 16 Then
' Do Nothing
ElseIf Left(pStrNumber, 14) = "2131" And Len(pStrNumber) = 15 Then
' Do Nothing
ElseIf Left(pStrNumber, 14) = "1800" And Len(pStrNumber) = 15 Then
' Do Nothing
Else
Exit Function
End If
Case "M"
Select Case Left(pStrNumber, 2)
Case "51", "52", "53", "54", "55"
' Do Nothing
Case Else
Exit Function
End Select
If Not Len(pStrNumber) = 16 Then Exit Function
Case "V"
If Not Left(pStrNumber, 1) = "4" Then Exit Function
If Not (Len(pStrNumber) = 13 or Len(pStrNumber) = 16) Then Exit Function
Case Else
' Unknown Card Type
Exit Function
End Select

' We got this far so the number passed all the rules!
ValidateCreditCard = True

End Function
' ------------------------------------------------------------------------------
Function LUHN(ByRef pStrDigits)

Dim lLngMaxPosition
Dim lLngPosition
Dim lLngSum' Sum of all positions
Dim lLngDigit' Current digit in specified position

' Initialize
lLngMaxPosition = Len(pStrDigits)
lLngSum = 0

' Read from right to left
For lLngPosition = lLngMaxPosition To 1 Step -1

' If we are working with an even digit (from the right)
If (lLngMaxPosition - lLngPosition) Mod 2 = 0 Then

lLngSum = lLngSum + CInt(Mid(pStrDigits, lLngPosition, 1))

Else

' Double the digit
lLngDigit = CInt(Mid(pStrDigits, lLngPosition, 1)) * 2

' shortcut adding sum of digits
If lLngDigit > 9 Then lLngDigit = lLngDigit - 9

lLngSum = lLngSum + lLngDigit

End If
Next
' A mod 10 check must not return any remainders
LUHN = lLngSum Mod 10 = 0
End Function
' ------------------------------------------------------------------------------
Function ParseDigits(ByRef pStrData)

' Strip all the numbers from a string
' (cleans up dashes and spaces)

Dim lLngMaxPosition
Dim lLngPosition

lLngMaxPosition = Len(pStrData)

For lLngPosition = 1 To lLngMaxPosition
If IsNumeric(Mid(pStrData, lLngPosition, 1)) Then
ParseDigits = ParseDigits & Mid(pStrData, lLngPosition, 1)
End If
Next
End Function

验证6种信用卡卡号的代码

推荐阅读

家庭自制榨菜腌制方法家庭自制榨菜腌制方法窍门

网站内部优化分析

云顶之弈魔幻AOE卡牌流阵容搭配分享魔幻AOE卡牌流玩法技巧

肛裂会自愈吗？

#支教之行#打球篇

入伏要注意什么 2021入伏就是出梅了吗

跨境电商是做什么的电商属于什么端，关于电商

学美发多久能学成呢？

幼猫感冒吃什么药猫感冒吃什么药

QVE音频剪辑软件怎么剪辑音频？

气虚会对月经有影响吗

安卓边框渐变,边框line可设置为渐变颜色或仅显示一种颜色

Apollo热发布配置

王者训练营怎么关冷却时间

陆绎八岁了是什么梗

拍一拍有什么用处

焦作市是什么气候

男人吃什么对肾脏好

西游记与本草纲目不得不说的秘密本草纲目

佳能G9X相机照相黑色是怎么回事